Guardar y leer archivos CSV en Julia (17ª parte – ¡Hola Julia!)

Ahora que sabemos seleccionar filas, columnas y combinar varios DataFrames en Julia es un buen momento para aprender a importar datos desde archivos. Uno de los formatos más populares para el intercambio de datos es CSV, ya que son archivos de texto que pueden usarse con todos los programas. Así que vamos a ver un paquete con el que poder guardar y leer archivos CSV en Julia

Librerías para archivos CSV en Julia

Antes de poder trabajar con un archivo CSV en Julia es necesario instalar un paquete para ello. Ya que no existe una función por defecto para ello. Dos de los paquetes más populares son CSVFiles.jl y CSV.jl.

En la entrada vamos a ver solamente el paquete CSVFiles. Un paquete que forma parte del Queryverse, por lo que aprenderemos un API que es similar al de otros paquetes. Facilitando así el aprendizaje de estos, como es el caso de ExcelFiles que veremos en la próxima entrada.

El proceso de instalación es sencillo. Simplemente en una sesión de Julia debemos importar el paquete Pkg y mediante la función add() incluir el nuevo paquete. Algo que solo se tendrá que hacer una vez ejecutando el siguiente código.

using Pkg

Pkg.add("CSVFiles")

Guardar un DataFrame en un archivo CSV

Antes de poder guardar un DataFrame en un archivo CSV es necesario tener uno en memoria, por lo que vamos a usar el mismo que vimos en la entrada anterior de clientes. Ahora, para guardar el objeto en un archivo CSV solamente debemos llamar a la función save() con el nombre del archivo y el DataFrame. Así de sencillo.

using DataFrames
using CSVFiles

clients = DataFrame(
    id=[1,2,3,4,5],
    first_name=["Oralie" ,"Imojean" ,"Michele", "Ailbert", "Stevy"],
    last_name=["Fidgeon" ,"Benet" ,"Woodlands", "Risdale", "MacGorman"],
    age=[30 ,21 ,missing ,22, 24])

save("clients.csv", clients)

En el ejemplo se puede ver que la función save() identifica el tipo de archivo por la extensión y guarda en el el DataFrame. Algo que podemos comprobar simplemente cargando el archivo.

"id","first_name","last_name","age"
1,"Oralie","Fidgeon",30
2,"Imojean","Benet",21
3,"Michele","Woodlands",NA
4,"Ailbert","Risdale",22
5,"Stevy","MacGorman",24

Pudiéndose observar en el archivo que por defecto se usa como separador de valores la coma. Además, también se puede observar que los valores tipo Missing se convierten en NA. Opciones que se pueden cambiar si lo necesitamos. Por ejemplo, se puede crear un archivo CSV con el punto y como como delimitado ( delim), con NULL para los valores tipo Missing ( nastring) y sin cabecera ( header).

save("clients.csv", clients, delim=';', nastring="NULL", header=false)

1;"Oralie";"Fidgeon";30
2;"Imojean";"Benet";21
3;"Michele";"Woodlands";NULL
4;"Ailbert";"Risdale";22
5;"Stevy";"MacGorman";24

Guardar con otra extensión

Muchas veces nos encontramos con archivos CSV que tienen otra extensión como puede ser TXT o DAT. Así que, si la función save() se basa en la extensión es necesario indicar que se desea guardar en otro formato. Lo que se puede hacer con File(), al que se le puede indicar el formato como primer parámetro y el nombre del archivo como segundo. Así para guardar los datos en clientes.txt en formato CSV solo hay que usar el siguiente código.

save(File(format"CSV", "clients.txt"), clients)

Comprimir el archivo

Cuando trabajamos con archivos grandes puede ser una buena idea guardar estos comprimidos. Ya que al ser los CSV archivos de texto es fácil conseguir buenas compresiones. Algo que también se puede hacer en Python. Aunque en Julia es más fácil, solamente hay que indicar la extensión gz en el nombre del archivo que se le indica a File(). Lo que creará un archivo comprimido.

save(File(format"CSV", "clients.csv.gz"), clients)

Leer archivos CSV en Julia

Ahora que ya hemos creado varios archivos CSV podemos ver como cargarlo. La idea es sencilla, solamente hay que usar la función load() y pasar el resultado al constructor de DataFrames. Algo como lo que se muestra en el siguiente código.

df = DataFrame(load("clients.csv"))

4×1 DataFrame
│ Row │ 1;"Oralie";"Fidgeon";30      │
│     │ String                       │
├─────┼──────────────────────────────┤
│ 1   │ 2;"Imojean";"Benet";21       │
│ 2   │ 3;"Michele";"Woodlands";NULL │
│ 3   │ 4;"Ailbert";"Risdale";22     │
│ 4   │ 5;"Stevy";"MacGorman";24     │

En este ejemplo los datos no se cargan bien, debido a que el separador no es la coma, ya que la última vez que se guardó el CSV se había empleado el punto y coma a modo de separador. Siendo esto algo que se puede solucionar fácilmente indicando las opciones correctas mediante los mismos parámetros usados anteriormente. Además de indicar que no existe una columna de cabecera mediante header_exists y pasar un nombre para ellas con colnames.

df = DataFrame(load("clients.csv",delim=';', header_exists=false, colnames=["id", "name", "surname", "age"]))

5×4 DataFrame
│ Row │ id    │ name    │ surname   │ age     │
│     │ Int64 │ String  │ String    │ Int64?  │
├─────┼───────┼─────────┼───────────┼─────────┤
│ 1   │ 1     │ Oralie  │ Fidgeon   │ 30      │
│ 2   │ 2     │ Imojean │ Benet     │ 21      │
│ 3   │ 3     │ Michele │ Woodlands │ missing │
│ 4   │ 4     │ Ailbert │ Risdale   │ 22      │
│ 5   │ 5     │ Stevy   │ MacGorman │ 24      │

Importar archivos comprimidos

Finalmente, para volver a cargar los archivos comprimidos se tiene que hacer los mismo que para guardar. Usar File() para indicar el formato del archivo y el nombre.

df = load(File(format"CSV", "clients.csv.gz")) |> DataFrame

En este caso, para transformar el archivo cargado en un DataFrame se ha usado una tubería (|>). Una forma alternativa para convertir los datos. Algo que también se puede usar para guardar los datos.

clients |> save("clients.csv")

Una forma sencilla de trabajar con CSV en Julia

En esta ocasión hemos visto cómo la librería CSVFiles ofrece un API sencillo y potente para trabajar con archivos CSV en Julia. En la próxima entrada de la serie veremos otra librería similar para trabajar con archivos Excel.

Publicidad